See the top rated post in this thread. Click here

Results 1 to 11 of 11

Thread: How to compare plays with CVCX ?

  1. #1
    Senior Member
    Join Date
    Jun 2015
    Location
    In orbit around Saturn
    Posts
    897


    Did you find this post helpful? Yes | No

    How to compare plays with CVCX ?

    With CVData, how to compare 2 betting variations ?
    Like https://www.blackjacktheforum.com/sh...l=1#post211788
    Last edited by Phoebe; 12-30-2016 at 09:31 AM. Reason: betting instead of play

  2. #2
    Random number herder Norm's Avatar
    Join Date
    Dec 2011
    Location
    The mote in God's eye
    Posts
    12,461
    Blog Entries
    59


    Did you find this post helpful? Yes | No
    I don't understand the question.
    "I don't think outside the box; I think of what I can do with the box." - Henri Matisse

  3. #3
    Senior Member
    Join Date
    Jun 2015
    Location
    In orbit around Saturn
    Posts
    897


    Did you find this post helpful? Yes | No
    I would know if two players with different counts will raise their bets simultaneously.

  4. #4
    Random number herder Norm's Avatar
    Join Date
    Dec 2011
    Location
    The mote in God's eye
    Posts
    12,461
    Blog Entries
    59


    Did you find this post helpful? Yes | No
    No way to do that.
    "I don't think outside the box; I think of what I can do with the box." - Henri Matisse

  5. #5
    Senior Member bigplayer's Avatar
    Join Date
    Dec 2011
    Location
    Las Vegas, NV
    Posts
    1,807


    Did you find this post helpful? Yes | No
    Quote Originally Posted by Philippe B View Post
    I would know if two players with different counts will raise their bets simultaneously.
    You should generally assume so. There will be some differences at lower counts but, for example, if High-Low calls for a max bet then someone betting Zen or some other count will likely also be making the same wager.

  6. #6


    Did you find this post helpful? Yes | No
    Answering your question from the other thread here. This is what I did....

    A1: <blank>
    A2: <blank>
    A3: 0
    A4 =A3+1
    drag and drop formula of A4 down until it's 260 (or however many cards into the shoe you wanna go. Do the same thing for other columns).

    B1: <blank>
    B2: <blank>
    B3: =RANDBETWEEN(1, 312-A3)

    Skip C column for now, will make sense once we fill in D through M columns

    D1: A
    E1: 2
    F1: 3
    etc.
    L1: 9
    M1:

    D2: 24
    E2: 24
    F2: 24
    etc.
    L2: 24
    M2: 96

    Now to C column.

    C1: <blank>
    C2: <blank>
    C3: =IF(B12<=D11,$D$10,IF(B12<=(D11+E11),$E$10,IF(B12< =SUM(D11:F11),$F$10,IF(B12<=SUM(D11:G11),$G$10,IF( B12<=SUM(D11:H11),$H$10,IF(B12<=SUM(D11:I11),$I$10 ,IF(B12<=SUM(D11:J11),$J$10,IF(B12<=SUM(D11:K11),$ K$10,IF(B12<=SUM(D11:L11),$L$10,IF(B12<=SUM(D11:M1 1),$M$10))))))))))

    ^ That's the formula I have. Replace the row numbers appropriately (my spreadsheet starts at row 10, not row 1....so subtract 9 from each number above).


    Formula looks like this (broken down). What you're doing is this --
    IF the random number in B is less than or equal to number of Aces remaining, then the drawn card is an Ace. If that's not true (ie: it's greater than number of aces remaining), then check to see if it's less than or equal to # of Aces + 2's remaining, if so, the draw card is a 2...if that's not true, check if it's less than or equal to number of Aces + 2's + 3's remaining....etc.

    =
    IF(B12<=D11,$D$10,
    IF(B12<=(D11+E11),$E$10,
    IF(B12<=SUM(D11:F11),$F$10,
    IF(B12<=SUM(D11:G11),$G$10,
    IF(B12<=SUM(D11:H11),$H$10,
    IF(B12<=SUM(D11:I11),$I$10,
    IF(B12<=SUM(D11:J11),$J$10,
    IF(B12<=SUM(D11:K11),$K$10,
    IF(B12<=SUM(D11:L11),$L$10
    ,IF(B12<=SUM(D11:M11),$M$10))))))))))



    Copy/paste that formula all the way down.


    Back to columns D through M.

    D3: =IF($C3=D$1,D2-1, D2)

    Copy/paste (or drag) that formula to column M, and all the way down (to 260 or w/e).


    Then in column Q (that's where I put it), put in the logic for tags of HILO or whatever count system you're using. Remember, C column tells you value of the draw card.

    Q1: "HILO RC"
    Q2: 0
    Q3: =IF(OR(C3=2,C3=3,C3=4,C3=5,C3=6),Q2+1,IF(OR(C3=10, C3="A"),Q2-1,IF(OR(C3=7,C3=8,C3=9),Q2)))

    Drag and drop Q3 all the way down. This is the running count for HILO. Change it as you see fit for other counts.

    R1: "HILO TC"
    R2: 0
    R3: =TRUNC(Q3/(N3/52))

    Drag and drop it all the way down. This is the HILO true count.


    Do the same thing but for a different count in columns S and T.

    In column U, write in the logic for how much the HILO player to wager. ie:

    U1: "HILO WAGER"
    U2: =IF(R2<=0, 25, IF(R2<=1, 50, IF(R2<=2, 100, IF(R2<=3, 200, IF(R2>=4, 400))))

    Then in column V, do the same thing, but with the other count's TC's.


    I openned another sheet, inserted a graph, then selected the U and V columns to represent the line graph.


    NOTE: This isn't 100% perfect, in the sense that the spreadsheet assumes the player is making a new wager for every card that is dealt, not for every round (ie: so there will be 260 "wagers" for 1 shoe dealt to 5 decks). Which basically means there is more volatility between bets, since it's assumed a new bet is made for every card dealt.

    You could expand on this, if you want. IE: For the wagers, you could do something where you only put in a wager every 5 or 6 or 7 cards dealt (if playing heads up). Could go as far as writing in the formulas to have the player actually play a hand and win or lose according to the outcome (player hand vs dealer hand), but that's probably a bit more complicated than its worth, IMO.


    EDIT: To refresh the random numbers and everything, you can find an empty space and type in =1. That's what I do, not sure if there's a fancier way to refresh everything.
    "Everyone wants to be rich, but nobody wants to work for it." -Ryan Howard [The Office]

  7. #7
    Senior Member
    Join Date
    Jun 2015
    Location
    In orbit around Saturn
    Posts
    897


    Did you find this post helpful? Yes | No
    Wow !
    Thank you. I will study this when I have a little (or rather a lot of :-)) time.

  8. #8


    Did you find this post helpful? Yes | No
    Quote Originally Posted by RollingStoned View Post
    <snip>EDIT: To refresh the random numbers and everything, you can find an empty space and type in =1. That's what I do, not sure if there's a fancier way to refresh everything.

    RollingStoned,

    The F9 key tells Excel to recalculate.

    Note that on a laptop or an Apple, you might need to hit another key at the same time to get the "normal" function to work.

    As for your methodology, though, I have a few reservations. One in particular is that you may generate a 6D shoe with more than 24 aces. Because of the method you used to assign a card rank to each of the 312 places in the shoe, the random numbers assigned to places 289 to 312 will all be less than 25, so those cards will all be assigned as aces. In a similar vein, your shoe will NEVER have 96 X's, since the X's can only appear within the first 96 cards drawn, so unless ALL of them are X's, you'll be playing with a short shoe.

    Hope this helps!

    Dog Hand

  9. #9


    Did you find this post helpful? Yes | No
    I think I understand what you're saying, but can you give an example of what you mean?

    Are you saying the 312'th card will only be able to be picked if it is picked first, but after that it wouldn't be picked? If so, look at the C column formula (I believe it's C, not on computer right now).
    "Everyone wants to be rich, but nobody wants to work for it." -Ryan Howard [The Office]

  10. #10


    2 out of 2 members found this post helpful. Did you find this post helpful? Yes | No

    Sorry, RollingStoned... I misread your original post

    RollingStoned,

    I apologize for misreading your original post detailing your method of using Excel to compare two counts: I failed to realize that your method does in fact "remove" each card as it is selected, and so it will in fact give an accurate number of each rank. I can only say that that's what I get for reading the post on a tablet instead of my computer

    By way of apology, allow me to give the method I would use, which I believe is somewhat simpler and perhaps more elegant than the one you described.

    Start a new Excel workbook, and type the information shown in the indicated cells:

    pic1.jpg

    Here, we'll be comparing HiLo with Zen. Most of the information shown is self-explanatory, though I made up the betting schedules: they each start at a TC of -999, because Excel will be looking for the largest entry less than or equal to the calculated TC, so we need to start at a value that's lower than any TC we'll see. For HiLo, we don't place a bet if the TC is below -4: this is equivalent to saying that we wong out at -5.

    The "Cards per Segment" is the resolution we'll use when computing "Decks Left in the Shoe": I've set it to 26 cards, so the "Decks Left" will be calculated to half-deck precision. If you want the Exact TC, set the CpS to 1.

    The "Same?", "H>Z?", and"Z>H?" will eventually have formulas below each to tell how oftent he two counts produce the Same bet, how often the HiLo bet is larger than the Zen bet, and how often the Zen bet is larger than the HiLo bet.

    Now select the range C2:E14 (to do this, first click inside (not on the border of) cell C2, then, while holding the left mouse button, drag down to cell E14, and finally release the left button). Then, type the name “tags” in the Name Box, as shown by the arrow in the figure:

    pic1-b.png

    This applies the name “tags” to this entire range of cells, so later we can use this name in our formulas. Next, select the range H3:I8 and name it “bets1”, then select the range J3:K8 and name it “bets2”.

    Next, in rows 16-19 enter the headings and the numbers 1 and 2, as shown:

    pic2.jpg

    Note that cells D17 and E17 each contain a zero: this is the Initial Running Count. Thus, if you want to compare UNBALANCED counts, you’ll have to enter the appropriate IRC.

    Then select cells A18 and A19. Next, left-click on the little square at the bottom right-hand corner of cell A19: the cursor will change to a "plus" sign. Drag all the way down to cell A329: while you're doing this, Excel will show a little box with the latest figure; you want to get to 312.

    Ok: now we've got position for all 312 cards in our 6D shoe!

    Now we have to enter a few formulas.

    Go back to cell B18 and type this formula: =RAND()
    This tells Excel to generate a random number between 0 and 1 for this cell. Select cell B18, left-click on the little square at the bottom right-hand corner of cell B18, and then drag down to cell B30 to produce a list of 13 random numbers. Now copy cells C2:C14 and paste into Cell C18: now each random number has a card next to it.

    In Cell D18 enter this formula: =D17+VLOOKUP($C18,tags,2,FALSE)
    Similarly, in Cell E18 enter this: =E17+VLOOKUP($C18,tags,3,FALSE)

    These VLOOKUP functions take the value in C18, at present an “A”, then looks in the leftmost column of the “tags” range for an exact match, thus, the first row. The D18 formula says to take the value in the corresponding row of column 2 (the HiLo Tag) of “tags”: so it retrieves a tag of -1. Note that the E18 formula looks instead in column 3 (the Zen Tag). In either case, the RC is then calculated by adding the current tag value to the previous value of the RC. By the way, the “FALSE” qualifier tells Excel that it must find an exact match in column 1: if it cannot find one, the function returns an error.

    In Cell F18 enter this: =$A$2-INT(A18/$A$6)*($A$6/52)
    This calculates the “Decks Left”, using the precision specified above in Cell A6. Don’t forget the $’s in the formula. What they do is force Excel to keep pointing at the same cells A2 and A6 even after we copy the formula to other cells in the spreadsheet.

    In Cell G18 enter this: =IF(D18=0,0,INT(D18/$F18))
    Here, if the RC is zero, then the TC is zero; for other RC’s, it calculates the TC as the floored integer of the ratio RC/(Decks Left).“Floored”, thus if the ratio is anywhere in the range 2.00 to 2.99, it’ll return a 2; in the range -3.01 to -4.00, it’ll return a -4. By the way, I put this “if” statement in so that when the shoe runs out (and the RC necessarily falls to zero), Excel won’t try to divide by 0.

    Copy Cell G18 to Cell H18. The formula will be similar to that above, except that in place of Cell D18 (the HiLo RC), this one will refer to Cell E18 (the Zen RC).

    In Cell I18 enter this: =VLOOKUP(G18,bets1,2)
    In Cell J18 enter this: =VLOOKUP(H18,bets2,2)

    Note that in these VLOOKUP’s, the last argument is missing: this tells Excel that instead of an exact match (which we used earlier for the “tags”), it should instead find the largest value in the first column that is less than or equal to the given value (that is, the TC calculated by HiLo or Zen), and return the corresponding wager.

    Next, in Cell K18 enter this: =SIGN(I18-J18)
    Thus, Column K will contain a “0” if both systems give the same bet, a “1” if HiLo’s bet is larger, and a “-1” if Zen’s bet is larger.


    Three more formulas to go!

    Now we’ll enter the formulas to calculate the “Same?”, "H>Z?",and "Z>H?" values.

    In Cell H14 enter this formula: =COUNTIF($K$18:$K$329,"=0")
    In Cell I14 enter this formula: =COUNTIF($K$18:$K$329,">0")
    In Cell J14 enter this formula: =COUNTIF($K$18:$K$329,"<0")

    These formulas will count the number for each category.

    At this point, your spreadsheet should look like this, except that your random numbers will (almost certainly) be different than those shown here:

    pic4.jpg

    Now select Cells D18:K18, then click the little square at the bottom right of K18 and drag down to Cell K30. This will copy the formulas into the range of cells D19:K30. Now we’ve got one-quarter of a deck!

    Now select Cells B18:K30, then hit CTRL-C to copy them. Now select the range B19:K329, then hit CTRL-V to paste: voila, we now have our six-deck shoe!

    Of course, the cards in our shoe are in a rather predictable order, aren’t they? How can we now randomize the order… hmm.

    Just kidding! I know the answer. Select the range B18:C329 (that is, all 312 random numbers and all 312 cards) and name the range S by typing an S in the Name Box.

    Now to shuffle the shoe, choose the Data tab in Excel’s ribbon (red arrow) and click the “A-Z” sort (green arrow), as shown here:

    pic5.jpg

    This will instantly sort the cards according to their random numbers from low to high, and then will instantly assign brand new random numbers to each card. Furthermore, the range named S will remain selected, so if you want to shuffle again, just click the “A-Z” sort again.

    If S is NOT selected, one easy way to select it once again is to click in the Name Box, type S, and hit the Enter key: Excel will then immediately select the S range for you.

    Hope this helps!

    Dog Hand

    P.S. If you have trouble with these directions, send me a message with an email address and I'll email a copy of the Excel file to you.
    Last edited by Dog Hand; 01-04-2017 at 08:33 PM. Reason: Fixed format

  11. #11
    Senior Member
    Join Date
    Jun 2015
    Location
    In orbit around Saturn
    Posts
    897


    Did you find this post helpful? Yes | No
    Could you send me the file, please.
    [email protected]

Similar Threads

  1. CVCX: Compare function
    By Phoebe in forum Software
    Replies: 2
    Last Post: 12-20-2015, 12:26 PM
  2. CVCX - Depth Based Index Plays
    By CheapShotArtist in forum Software
    Replies: 2
    Last Post: 05-14-2015, 01:06 PM
  3. california blackjack how does it compare to ap play
    By mhb in forum General Blackjack Forum
    Replies: 14
    Last Post: 01-01-2014, 06:58 PM
  4. Replies: 2
    Last Post: 06-18-2008, 08:38 AM

Bookmarks

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •  

About Blackjack: The Forum

BJTF is an advantage player site based on the principles of comity. That is, civil and considerate behavior for the mutual benefit of all involved. The goal of advantage play is the legal extraction of funds from gaming establishments by gaining a mathematic advantage and developing the skills required to use that advantage. To maximize our success, it is important to understand that we are all on the same side. Personal conflicts simply get in the way of our goals.